Useful IDE Scripting

Long-time reader Christian asked via the Suggestion Box for some examples of useful IDE scripting. Specifically, he was wondering how you'd automate a build, and perform a bit of file maintenance after the fact. Well, you're in luck, because I just so happen to have a bit of insights and useful tips on the topic! :-)

To perform a build, you're going to want to use the BuildApp method, provided by the context object. This method takes an integer platform parameter, and it returns to you a string to the built application on disk, and it's duty is to synchronously build the application you're asking for. This is going to be the cornerstone API of any IDE script that wants to automate builds, as you can imagine.

The other helpful API we're going to use is the DoShellCommand method. It takes a shell command as a parameter, and returns to you a string holding the results of the operation. This is what we're going to use to do the file maintenance after the application is built.

My example script is going to be very simple -- it's going to copy a few files from the root volume on Windows to next to the built application. It should be trivial for you to extrapolate more useful applications of this for your own projects. Without further ado:

  // Pulled these constants right out of the LR entry for IDE Script

  Const kBuildForWindows = 3

  Const kBuildForOSX = 8

  

  // Performs a build operation, and then copies a file in from the given path

  Sub DoBuild( platform as Integer, copyPath as String )

    dim path as String

    // Build for the platform given, and get the path to the executable back

    path = BuildApp( platform )

    

    if path <>"" then

      // Get the folder the executable file lives in

      dim parts() as String

      parts = Split( path, "\" )

      

      // Strip off the executable name itself

      parts.Remove( UBound( parts ) )

      

      // Put them all back together, and include the last path

      // separator at the end (so we have a valid folder path)

      path = Join( parts, "\" )

      

      // Now you can do your shell command

      call DoShellCommand( "copy /b /y " + copyPath + " " + path )

    end if

  End Sub

  

  DoBuild( kBuildForWindows, "c:\config.sys" )

  DoBuild( kBuildForOSX, "c:\autoexec.bat" )

Before I close, I'd like to discuss some interesting pieces of information that are easily overlooked when doing IDE scripts. The first one is the return value from BuildApp -- it gives you the path back to the executable file itself, or it returns an empty string if the build fails. So you can use this to get back an important distinction; did the build succeed or fail. The other tidbit has to do with DoShellCommand. There are some helpful environment variables set up for you by the command: IDE_PATH, PROJECT_FILE and PROJECT_PATH. Unfortunately, as of this writing (2008r3.1), they don't work on Windows (but do on Mac and Linux). The method itself also takes an optional timeout parameter, in case you don't want to wait too long for a command to finally fail.

Hopefully you'll find this little introduction to IDE scripting helpful. We designed it to make automating builds as easy as possible, and that's what we've been using it for internally for a long time. Now, you can do the same!